From d68964c7f36d199860a4aa24339abbf2ccae4c63 Mon Sep 17 00:00:00 2001
From: aj <aj@c6295689-39f2-0310-b995-f0e70906c6a9>
Date: Tue, 14 Aug 2007 05:55:56 +0000
Subject: [PATCH] keep libassuan as most users will not have this.

git-svn-id: https://www.opensc-project.org/svnp/opensc/trunk@3246 c6295689-39f2-0310-b995-f0e70906c6a9
---
 aclocal/Makefile.am  |  2 +-
 aclocal/libassuan.m4 | 76 ++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 77 insertions(+), 1 deletion(-)
 create mode 100644 aclocal/libassuan.m4

diff --git a/aclocal/Makefile.am b/aclocal/Makefile.am
index dc21ea7e..e37cdf12 100644
--- a/aclocal/Makefile.am
+++ b/aclocal/Makefile.am
@@ -2,4 +2,4 @@
 
 MAINTAINERCLEANFILES = Makefile.in
 
-EXTRA_DIST = acx_pthread.m4
+EXTRA_DIST = acx_pthread.m4 libassuan.m4
diff --git a/aclocal/libassuan.m4 b/aclocal/libassuan.m4
new file mode 100644
index 00000000..16b664ce
--- /dev/null
+++ b/aclocal/libassuan.m4
@@ -0,0 +1,76 @@
+dnl Autoconf macros for libassuan
+dnl       Copyright (C) 2002, 2003 Free Software Foundation, Inc.
+dnl
+dnl This file is free software; as a special exception the author gives
+dnl unlimited permission to copy and/or distribute it, with or without
+dnl modifications, as long as this notice is preserved.
+dnl
+dnl This file is distributed in the hope that it will be useful, but
+dnl WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
+dnl implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+
+
+dnl AM_PATH_LIBASSUAN([MINIMUM-VERSION,
+dnl                   [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
+dnl Test for libassuan and define LIBASSUAN_CFLAGS and LIBASSUAN_LIBS
+dnl
+AC_DEFUN([AM_PATH_LIBASSUAN],
+[ AC_ARG_WITH(libassuan-prefix,
+            AC_HELP_STRING([--with-libassuan-prefix=PFX],
+                           [prefix where LIBASSUAN is installed (optional)]),
+     libassuan_config_prefix="$withval", libassuan_config_prefix="")
+  if test x$libassuan_config_prefix != x ; then
+     libassuan_config_args="$libassuan_config_args --prefix=$libassuan_config_prefix"
+     if test x${LIBASSUAN_CONFIG+set} != xset ; then
+        LIBASSUAN_CONFIG=$libassuan_config_prefix/bin/libassuan-config
+     fi
+  fi
+
+  AC_PATH_PROG(LIBASSUAN_CONFIG, libassuan-config, no)
+  min_libassuan_version=ifelse([$1], ,0.0.1,$1)
+  AC_MSG_CHECKING(for LIBASSUAN - version >= $min_libassuan_version)
+  ok=no
+  if test "$LIBASSUAN_CONFIG" != "no" ; then
+    req_major=`echo $min_libassuan_version | \
+               sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
+    req_minor=`echo $min_libassuan_version | \
+               sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
+    req_micro=`echo $min_libassuan_version | \
+               sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
+    libassuan_config_version=`$LIBASSUAN_CONFIG $libassuan_config_args --version`
+    major=`echo $libassuan_config_version | \
+               sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
+    minor=`echo $libassuan_config_version | \
+               sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
+    micro=`echo $libassuan_config_version | \
+               sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
+    if test "$major" -gt "$req_major"; then
+        ok=yes
+    else 
+        if test "$major" -eq "$req_major"; then
+            if test "$minor" -gt "$req_minor"; then
+               ok=yes
+            else
+               if test "$minor" -eq "$req_minor"; then
+                   if test "$micro" -ge "$req_micro"; then
+                     ok=yes
+                   fi
+               fi
+            fi
+        fi
+    fi
+  fi
+  if test $ok = yes; then
+    LIBASSUAN_CFLAGS=`$LIBASSUAN_CONFIG $libassuan_config_args --cflags`
+    LIBASSUAN_LIBS=`$LIBASSUAN_CONFIG $libassuan_config_args --libs`
+    AC_MSG_RESULT(yes)
+    ifelse([$2], , :, [$2])
+  else
+    LIBASSUAN_CFLAGS=""
+    LIBASSUAN_LIBS=""
+    AC_MSG_RESULT(no)
+    ifelse([$3], , :, [$3])
+  fi
+  AC_SUBST(LIBASSUAN_CFLAGS)
+  AC_SUBST(LIBASSUAN_LIBS)
+])